More Difficult Early Game Progression

How did you use MineTweaker? Discuss your experience here! You can post your MineTweaker-enabled modpack here, too.

More Difficult Early Game Progression

Postby redbaron148 » Sun Jul 27, 2014 9:00 pm

My friends and I love the Iguana Tweaks mod for Tinkers Construct. Unfortunately, this has yet to be updated to 1.7.10 so I decided I would try to implement the difficulty progression of Iguana Tweaks for TiC using Mine Tweaker 3 and Mod Organizer. Here is my initial attempt at making a similar tech tree. This script changes the mining level of Tinkers Construct tools and forces you to fight/behead certain mobs and 'glue' the parts to the tools to upgrade them to the next tier.

In this script, the progression goes:
1. Skeleton Skull glued to a Paper Sword gives you a beheading sword. (Using the ruins mod skele skulls spawn in structures, you can adjust the beheading upgrade items however you would like)
2. Creeper or Zombie head glued to a Paper Pickaxe gives you a Iron Level paper pickaxe.
3. Ender pearl glued to a Iron Level paper pickaxe gives you a Steel Level paper pickaxe. (redstone level)
4. Diamond glued to a Steel Level paper pickaxe gives you an Obsidian Level paper pickaxe.
5. Wither Skull or Ghast Tear glued to a Colbalt Level paper pickaxe.

The point of me sharing this is to demonstrate how powerful this mod can be and to provide some iguana tweaks replacements until the main iguana tweaks mod is updated to 1.7.10.

: [Select all] [/] [] (IguanaTweaksReplica.zs)
  1. // Tinkers Construct Tweaks
  2. val stoneLevel      = 0;
  3. val ironLevel       = 1;
  4. val redstoneLevel   = 2;
  5. val obsidianLevel   = 3;
  6. val cobaltLevel     = 4;
  7. val manyullynLevel  = 5;
  8.  
  9. // Tinkers construct materials
  10. val wood        = 0;
  11. val stone       = 1;
  12. val iron        = 2;
  13. val flint       = 3;
  14. val cactus      = 4;
  15. val bone        = 5;
  16. val obsidian    = 6;
  17. val netherrack  = 7;
  18. val slime       = 8;
  19. val paper       = 9;
  20. val cobalt      = 10;
  21. val ardite      = 11;
  22. val manyullyn   = 12;
  23. val copper      = 13;
  24. val bronze      = 14;
  25. val alumite     = 15;
  26. val steel       = 16;
  27. val blueSlime   = 17;
  28. val pigIron     = 18;
  29.  
  30. // Define the glue ore dictionary (i'm using IC2 so I added sticky resin to the glue dictionary)
  31. val glue = <ore:glue>;
  32. glue.add(<TConstruct:materials:36>);
  33. glue.add(<IC2:itemHarz>);
  34. glue.add(<TConstruct:strangeFood>);
  35. glue.add(<minecraft:slime_ball>);
  36.  
  37. // Adjust pickaxe mining levels
  38. mods.tconstruct.ToolStats.setHarvestLevel("Slime",stoneLevel);
  39. mods.tconstruct.ToolStats.setHarvestLevel("BlueSlime",stoneLevel);
  40. mods.tconstruct.ToolStats.setHarvestLevel("Paper",stoneLevel);
  41. mods.tconstruct.ToolStats.setHarvestLevel("Cactus",stoneLevel);
  42. mods.tconstruct.ToolStats.setHarvestLevel("Wood",stoneLevel);
  43. mods.tconstruct.ToolStats.setHarvestLevel("Netherrack",stoneLevel);
  44. mods.tconstruct.ToolStats.setHarvestLevel("Bone",stoneLevel);
  45. mods.tconstruct.ToolStats.setHarvestLevel("Flint",stoneLevel);
  46. mods.tconstruct.ToolStats.setHarvestLevel("Stone",stoneLevel);
  47. mods.tconstruct.ToolStats.setHarvestLevel("Copper",stoneLevel);
  48. mods.tconstruct.ToolStats.setHarvestLevel("Bronze",ironLevel);
  49. mods.tconstruct.ToolStats.setHarvestLevel("Iron",ironLevel);
  50. mods.tconstruct.ToolStats.setHarvestLevel("PigIron",redstoneLevel);
  51. mods.tconstruct.ToolStats.setHarvestLevel("Steel",redstoneLevel);
  52. mods.tconstruct.ToolStats.setHarvestLevel("Obsidian",obsidianLevel);
  53. mods.tconstruct.ToolStats.setHarvestLevel("Alumite",obsidianLevel);
  54. mods.tconstruct.ToolStats.setHarvestLevel("Ardite",cobaltLevel);
  55. mods.tconstruct.ToolStats.setHarvestLevel("Cobalt",cobaltLevel);
  56. mods.tconstruct.ToolStats.setHarvestLevel("Manyullyn",manyullynLevel);
  57.  
  58. val paperDismembermentTool  = <TConstruct:broadsword>.withTag({InfiTool: {Unbreaking: 0, Damage: 0, Extra: 0, MiningSpeed2: 200, HarvestLevel: 0, Head: paper, Built: 1 as byte, BaseDurability: 9, Beheading: 10, RenderExtra: 0, Accessory: 0, Modifiers: 0, RenderHead: paper, Handle: paper, HarvestLevel2: 0, RenderHandle: paper, Attack: 4, Shoddy: 0.0 as float, MiningSpeed: 200, ModDurability: 0.0 as float, BonusDurability: 0, Effect1: 13, Broken: 0 as byte, TotalDurability: 9, RenderAccessory: paper}, display: {Name: "Paper Dismemberment Tool"}});
  59. val upgradablePaperSword    = <TConstruct:broadsword>.withTag({InfiTool: {RenderHead: paper, RenderHandle: paper, RenderAccessory: paper}});
  60.  
  61. // Items used to upgrade to the next level of pickaxe.
  62. val beheadingUpgrade            = <ore:upgradeBeheading>;
  63. val stoneToIronUpgrade          = <ore:upgradeStoneToIron>;
  64. val ironToRedstoneUpgrade       = <ore:upgradeIrontoRedstone>;
  65. val redstoneToObsidianUpgrade   = <ore:upgradeRedstoneToObsidian>;
  66. val obsidianToCobaltUpgrade     = <ore:upgradeObsidianToCobalt>;
  67.  
  68. beheadingUpgrade.add(<minecraft:skull>);
  69. stoneToIronUpgrade.add(<minecraft:skull:2>);
  70. stoneToIronUpgrade.add(<minecraft:skull:4>);
  71. ironToRedstoneUpgrade.add(<minecraft:ender_pearl>);
  72. redstoneToObsidianUpgrade.add(<minecraft:diamond>);
  73. obsidianToCobaltUpgrade.add(<minecraft:skull:1>);
  74. obsidianToCobaltUpgrade.add(<minecraft:ghast_tear>);
  75.  
  76. // Picks which can be upgraded
  77. var upgradableStoneLevelPick    = <TConstruct:pickaxe>.withTag({InfiTool: {HarvestLevel: stoneLevel, RenderHead: paper, RenderHandle: paper, RenderAccessory: paper}});
  78. var upgradableIronLevelPick     = <TConstruct:pickaxe>.withTag({InfiTool: {HarvestLevel: ironLevel, RenderHead: iron, RenderHandle: paper, RenderAccessory: paper},display: {Name: "Iron Paper Pickaxe"}});
  79. var upgradableRedstoneLevelPick = <TConstruct:pickaxe>.withTag({InfiTool: {HarvestLevel: redstoneLevel, RenderHead: steel, RenderHandle: paper, RenderAccessory: paper},display: {Name: "Steel Paper Pickaxe"}});
  80. var upgradableObsidianLevelPick = <TConstruct:pickaxe>.withTag({InfiTool: {HarvestLevel: obsidian, RenderHead: obsidian, RenderHandle: paper, RenderAccessory: paper},display: {Name: "Obsidian Paper Pickaxe"}});
  81.  
  82. // Picks produced by upgrading
  83. var upgradedStoneLevelPick      = <TConstruct:pickaxe>.withTag({InfiTool: {Unbreaking: 0, Damage: 0, HarvestLevel: ironLevel, Head: paper, Built: 1 as byte, BaseDurability: 9, Accessory: 9, Modifiers: 0, RenderHead: iron, Handle: paper, Shoddy: 0.0 as float, Attack: 1, RenderHandle: paper, MiningSpeed: 300, ModDurability: 0.0 as float, BonusDurability: 0, Broken: 0 as byte, TotalDurability: 9, RenderAccessory: paper}, display: {Name: "Iron Paper Pickaxe"}});
  84. var upgradedIronLevelPick       = <TConstruct:pickaxe>.withTag({InfiTool: {Unbreaking: 0, Damage: 0, HarvestLevel: redstoneLevel, Head: paper, Built: 1 as byte, BaseDurability: 9, Accessory: 9, Modifiers: 0, RenderHead: steel, Handle: paper, Shoddy: 0.0 as float, Attack: 1, RenderHandle: paper, MiningSpeed: 400, ModDurability: 0.0 as float, BonusDurability: 0, Broken: 0 as byte, TotalDurability: 9, RenderAccessory: paper}, display: {Name: "Steel Paper Pickaxe"}});
  85. var upgradedRedstoneLevelPick   = <TConstruct:pickaxe>.withTag({InfiTool: {Unbreaking: 0, Damage: 0, HarvestLevel: obsidianLevel, Head: paper, Built: 1 as byte, BaseDurability: 9, Accessory: 9, Modifiers: 0, RenderHead: obsidian, Handle: paper, Shoddy: 0.0 as float, Attack: 1, RenderHandle: paper, MiningSpeed: 500, ModDurability: 0.0 as float, BonusDurability: 0, Broken: 0 as byte, TotalDurability: 9, RenderAccessory: paper}, display: {Name: "Obsidian Paper Pickaxe"}});
  86. var upgradedObsidianLevelPick   = <TConstruct:pickaxe>.withTag({InfiTool: {Unbreaking: 0, Damage: 0, HarvestLevel: cobaltLevel, Head: paper, Built: 1 as byte, BaseDurability: 9, Accessory: 9, Modifiers: 0, RenderHead: cobalt, Handle: paper, Shoddy: 0.0 as float, Attack: 1, RenderHandle: paper, MiningSpeed: 600, ModDurability: 0.0 as float, BonusDurability: 0, Broken: 0 as byte, TotalDurability: 9, RenderAccessory: paper}, display: {Name: "Cobalt Paper Pickaxe"}});
  87.  
  88. // Add recipes for upgrading
  89. recipes.addShapeless(paperDismembermentTool, [beheadingUpgrade,glue,upgradablePaperSword]);
  90. recipes.addShapeless(upgradedStoneLevelPick,[upgradableStoneLevelPick,glue,stoneToIronUpgrade]);
  91. recipes.addShapeless(upgradedIronLevelPick,[upgradableIronLevelPick,glue,ironToRedstoneUpgrade]);
  92. recipes.addShapeless(upgradedRedstoneLevelPick,[upgradableRedstoneLevelPick,glue,redstoneToObsidianUpgrade]);
  93. recipes.addShapeless(upgradedObsidianLevelPick,[upgradableObsidianLevelPick,glue,obsidianToCobaltUpgrade]);
  94.  
  95. // Remove ore block recipes (use tinkers construct basins for creating blocks)
  96. recipes.remove(<TConstruct:MetalBlock>);    // Cobalt
  97. recipes.remove(<TConstruct:MetalBlock:1>);  // Ardite
  98. recipes.remove(<TConstruct:MetalBlock:2>);  // Manyullyn
  99. recipes.remove(<TConstruct:MetalBlock:3>);  // Copper
  100. recipes.remove(<TConstruct:MetalBlock:4>);  // Bronze
  101. recipes.remove(<TConstruct:MetalBlock:5>);  // Tin
  102. recipes.remove(<TConstruct:MetalBlock:6>);  // Aluminium
  103. recipes.remove(<TConstruct:MetalBlock:7>);  // Aluminium Brass
  104. recipes.remove(<TConstruct:MetalBlock:8>);  // Alumite
  105. recipes.remove(<TConstruct:MetalBlock:9>);  // Steel
GeSHi © Codebox Plus
User avatar
redbaron148
 
Posts: 13
Joined: Sat Jul 19, 2014 9:01 pm

Re: More Difficult Early Game Progression

Postby papuqoniwe » Thu Oct 25, 2018 1:15 pm

thank you
I got the more difficulties that all are on the game progression this was all that I got on this forum it has all the news on it. I have to able the attend all ukessay reviews this was all on it to get the informative stuff.
papuqoniwe
 
Posts: 1
Joined: Thu Oct 25, 2018 1:13 pm


Return to Usage Discussions

Who is online

Users browsing this forum: No registered users and 1 guest